IDEA POJO开发神器之—Groovy

时间:2020-7-30 作者:admin


IDEA POJO开发神器之—Groovy

暂时只对 MySQL进行了测试
项目使用 Lombok MyBatis-Plus

一:使用步骤

  1. 首先在项目右侧找到 DataBase 如图 没有请参考 idea中database不显示问题
    IDEA POJO开发神器之---Groovy
    2.点开之后进行数据库连接(注意没有驱动的请下载相关数据库驱动)具体步骤如图
    IDEA POJO开发神器之---Groovy
    点开 + 号
    IDEA POJO开发神器之---Groovy
    选择Date Source
    IDEA POJO开发神器之---Groovy
    找到相应的数据库 这里我使用的是 mysql
    IDEA POJO开发神器之---Groovy
    如果没有 Dirver 请下载 idea 会在窗口左下角给提示(这里具体在什么位置我也记不清楚)输入相关连接信息
    IDEA POJO开发神器之---Groovy
    过程中出现任何问题,请在留言区留言(萌新基本全天在线)连接上之后如果没有需要的数据可以点击如下图方式
    IDEA POJO开发神器之---Groovy
    IDEA POJO开发神器之---Groovy
    先设置groovy
    IDEA POJO开发神器之---Groovy

替换(有些地方需要注意,具体看下方源码)

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.time.LocalDate

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

// 此处指定包路径,路径需要自行维护;
packageName = "com.qgy.web.entity;"
// 此处指定对应的类型映射,可按需修改,目前tinyint如果要映射到自定义枚举类型,只能手动修改
typeMapping = [
        (~/(?i)bigint/)                   : "Long",
        (~/(?i)int/)                      : "Integer",
        (~/(?i)tinyint/)                  : "Boolean",
        (~/(?i)float|double|decimal|real/): "BigDecimal",
        (~/(?i)time|datetime|timestamp/)  : "LocalDateTime",
        (~/(?i)date/)                     : "LocalDate",
        (~/(?i)/)                         : "String"
]

// 上面用到类和它的导入路径的之间的映射
importMap = [
        "BigDecimal"   : "java.math.BigDecimal",
        "LocalDate"    : "java.time.LocalDate",
        "LocalDateTime": "java.time.LocalDateTime",
]

// 导入路径列表,下面引用的时候会去重,也可以直接声明成一个 HashSet
importList = []

// 弹出选择文件的对话框
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaName(table.getName(), true) + "Entity"
    def fields = calcFields(table)
    new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "utf-8")).withPrintWriter { out -> generate(out, className, fields, table) }
}

// 从这里开始,拼实体类的具体逻辑代码
def generate(out, className, fields, table) {
    out.println "package $packageName"
    out.println ""
    // 引入所需的包
    out.println "import lombok.Data;"
    out.println "import lombok.EqualsAndHashCode;"
    out.println "import lombok.experimental.Accessors;"
    out.println "import com.baomidou.mybatisplus.annotation.*;"
    out.println "import java.io.Serializable;"
    // 去重后导入列表
    importList.unique().each() { pkg ->
        out.println "import " + pkg + ";"
    }
    out.println ""
    // 添加类注释
    out.println "/**"
    // 如果添加了表注释,会加到类注释上
    if (isNotEmpty(table.getComment())) {
        out.println " * " + table.getComment()
    }
    out.println " *"
    out.println " * @author 输入作者"
    out.println " * @date " + LocalDate.now()
    out.println " */"
    // 添加类注解
    out.println "@Data"
    out.println "@EqualsAndHashCode(callSuper = false)"
    out.println "@Accessors(chain = true)"
    out.println "@TableName(\"${table.getName()}\")"
    out.println "public class $className implements Serializable {"
    out.println ""
    out.println genSerialID()
    boolean isId = true
    // 遍历字段,按下面的规则生成
    fields.each() {
        // 输出注释
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        // 这边默认第一个字段为主键,实际情况大多数如此,遇到特殊情况可能需要手动修改
        if (isId) {
            out.println "\t@TableId(type = IdType.AUTO)"
            isId = false
        }
        if ((it.annos + "").indexOf("[@Id]") >= 0) out.println "\t@Id"

        if (it.annos != "") out.println " ${it.annos.replace("[@Id]", "")}"

        out.println "\tprivate ${it.type} ${it.name};"
        out.println ""
    }
    out.println ""
    out.println "}"
}

def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        if (importMap.containsKey(typeStr)) {
            importList.add(importMap.get(typeStr))
        }
        fields += [[
                           name   : javaName(col.getName(), false),
                           type   : typeStr,
                           comment: col.getComment(),
                           annos  : "\t@TableField(\"" + col.getName() + "\" )"
                   ]]
    }
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

选中需要的数据库,找到需要生成实体类的表这里我就随便选择一个。右键选择
IDEA POJO开发神器之---Groovy
在左侧列表找到文件名之后点击会有弹窗选择你要存放的地方点击🆗就行了,效果如下

package com.qgy.web.entity;

import lombok.Data;
import lombok.EqualsAndHashCode;
import lombok.experimental.Accessors;
import com.baomidou.mybatisplus.annotation.*;
import java.io.Serializable;
import java.time.LocalDateTime;

/**
 * 超级管理员账号信息表
 *
 * @author rog
 * @date 2020-07-20
 */
@Data
@EqualsAndHashCode(callSuper = false)
@Accessors(chain = true)
@TableName("sys_super")
public class SysSuperEntity implements Serializable {

	private static final long serialVersionUID =  5132404354445122973L;
	/**
	 * 主键id标识
	 */
	@TableId(type = IdType.AUTO)
 	@TableField("id" )
	private Integer id;

	/**
	 * 管理员id唯一标识
	 */
 	@TableField("account_id" )
	private String accountId;

	/**
	 * 管理员账号
	 */
 	@TableField("account" )
	private String account;

	/**
	 * 管理员密码
	 */
 	@TableField("account_password" )
	private String accountPassword;

	/**
	 * 上一次登录ip
	 */
 	@TableField("account_ip_last" )
	private String accountIpLast;

	/**
	 * 当前登录ip
	 */
 	@TableField("account_ip_now" )
	private String accountIpNow;

	/**
	 * 最近一次登录时间
	 */
 	@TableField("login_time" )
	private LocalDateTime loginTime;

	/**
	 * 是否启用
	 */
 	@TableField("isEnable" )
	private Integer isEnable;

}

好了本期分享就到这里,第一次发博客排版不是太好看,欢迎各位在评论区留言指出不足的地方,我会立即改正

声明:本文内容由互联网用户自发贡献自行上传,本网站不拥有所有权,未作人工编辑处理,也不承担相关法律责任。如果您发现有涉嫌版权的内容,欢迎进行举报,并提供相关证据,工作人员会在5个工作日内联系你,一经查实,本站将立刻删除涉嫌侵权内容。